libraryextensions/blender/demos/NeonCity.xtl

NeonCity.xtl -- a city at night after rain, worked out as arrays and ray-traced (Cycles.xtl): an avenue running north between two walls of towers, six lots deep on each side, every lot's tower a few rows of a table -- a body, a narrower tier, sometimes a spire -- with a height, a footprint and a skin of its own from a hash of its number; screens on the walls that face the avenue, bands of neon, signs, lamps, steam, bridges across, cars on the ground and in the air, and a camera that comes down from the skyline to the puddles. Nothing is drawn by hand and nothing is loaded: another seed is another city (nc:c_ity). Shared by the demo (demos/city.xtl: stills), its preview and film, and its test. Import: "nc:" u_se< "NeonCity"

source · imports cy: extensions/blender/lib/Cycles.xtl

Numbers

ˡseed : Int

value · line 21

nc:seed: the film's city: every random choice is a hash of the seed and of the thing's own number, so the same seed is the same city and another seed another

ˡseed ← 7
Used in: ˡs̲cene, scene

ˡseconds : Float

value · line 24

nc:seconds: the film's length

ˡseconds ← 15.0

ˡmedia : Char

value · line 28

nc:media: where the film finds the screens' pictures, from the blender extension's directory (where its demos run)

ˡmedia ← "../three/web/static/media"
Used in: ˡs̲cene

ʰc̲ols : Any b => (Int, a) -> b -> a

function (private) · line 31
ʰc̲ols ← { (k, v) z → 2 1 t̲ranspose (k c̲at (t̲ally v) d̲iv k) r̲eshape v }

ˡr̲and : Any a => (Int, Int, Int) -> a -> Float

function · line 39

(numbers, salt, seed) nc:r_and 0: a number from 0 to 1 for each whole number, the same every time: a hash of it, the salt (which choice this is) and the seed, in whole numbers, so every machine agrees

      "nc:" u̲se< "NeonCity"
      s̲hape (0 1 2 3, 1, 7) ⁿᶜr̲and 0
4
ˡr̲and ← { (i, salt, seed) z →
  a ← (i + 17) × 7919 + (salt + 13 × seed) × 104729
  b ← i + 31 + salt
  (f̲loat ((a m̲od 65521) × b m̲od 65521) m̲od 65521) ÷ 65521.0
}

ʰb̲ox : Any a => (Float, Float, Float, Float, Float, Float) -> a -> Float

function (private) · line 47
ʰb̲ox ← { (x, y, e, w, d, h) z → (7, x c̲at y c̲at e c̲at w c̲at d c̲at h c̲at 0.0 × x) ʰc̲ols 0 }

ʰf̲ill : Num a => (Int, a) -> Float

function (private) · line 50
ʰf̲ill ← { (n, x) → n r̲eshape f̲loat x }

The lots

cols : Int

value (private) · line 55
cols ← 6
Used in: per, blocks

rows : Int

value (private) · line 56
rows ← 20
Used in: per, col, row, blocks, bcol, brow

per : Int

value (private) · line 57
per ← cols × rows
Used in: lots, side, col, row

lots : Int

value (private) · line 58
lots ← 2 × per

id : Int

value (private) · line 60
id ← (r̲ange lots) − 1

side : Float

value (private) · line 61
side ← (f̲loat 2 × id d̲iv per) − 1.0
Used in: lx, ˡs̲creens

col : Int

value (private) · line 62
col ← (id m̲od per) d̲iv rows

row : Int

value (private) · line 63
row ← (id m̲od per) m̲od rows
Used in: ly

lx : Float

value (private) · line 66
lx ← side × 19.5 + (17.0 × f̲loat col) + 12.0 × f̲loat col d̲iv 2
Used in: ˡl̲ots

ly : Float

value (private) · line 67
ly ← -234.5 + (19.0 × f̲loat row) + 12.0 × f̲loat row d̲iv 2
Used in: ˡl̲ots

ˡl̲ots : Int -> Float

function · line 79

nc:l_ots seed: the lots as a table, a row each: x y (its middle), the tower's height, its width and depth, its skin (0 to 2), whether it has a tier and a spire (1 or 0), how far back from the avenue it is (0 the first), and where its body ends (the tier begins there). Heights: most low, a few very tall; taller by the avenue, and never under 45 on it, so the avenue is a canyon; a tower over 60 has a narrower tier, and some of those a spire.

      "nc:" u̲se< "NeonCity"
      s̲hape ⁿᶜl̲ots 7
240 10
ˡl̲ots ← { seed →
  u ← (id, 1, seed) ˡr̲and 0
  rough ← (((26.0 + 150.0 × u × u) × 1.25 − 0.09 × f̲loat col) m̲ax
    45.0 × f̲loat 1 × col = 0)
  wide ← 15.5 − 3.0 × (id, 2, seed) ˡr̲and 0
  deep ← 17.5 − 3.0 × (id, 3, seed) ˡr̲and 0
  skin ← f̲loat f̲loor 3.0 × (id, 4, seed) ˡr̲and 0
  tiered ← f̲loat 1 × rough > 60.0
  body ← rough × (1.0 − tiered) + tiered × 0.55 + 0.3 × (id, 5, seed) ˡr̲and 0
  spired ← tiered × f̲loat 1 × ((id, 6, seed) ˡr̲and 0) > 0.7
  (10, lx c̲at ly c̲at rough c̲at wide c̲at deep c̲at skin c̲at tiered c̲at spired c̲at (f̲loat col) c̲at body) ʰc̲ols 0
}
Used in: ʰb̲uilt

ˡt̲owers : (Num a, Any b) => (Float, a) -> b -> Float

function · line 97

(lots, k) nc:t_owers 0: the boxes of every tower wearing skin k (0 to 2): bodies, then tiers, then spires

      "nc:" u̲se< "NeonCity"
      2 s̲elect s̲hape (ⁿᶜl̲ots 7, 0) ⁿᶜt̲owers 0
7
ˡt̲owers ← { (t, k) z →
  x ← 1 s̲elect₂ t
  y ← 2 s̲elect₂ t
  rough ← 3 s̲elect₂ t
  wide ← 4 s̲elect₂ t
  deep ← 5 s̲elect₂ t
  body ← 10 s̲elect₂ t
  worn ← (6 s̲elect₂ t) = f̲loat k
  tiered ← worn ∧ (7 s̲elect₂ t) > 0.5
  spired ← worn ∧ (8 s̲elect₂ t) > 0.5
  bodies ← worn r̲eplicate₁ (x, y, body ÷ 2.0, wide, deep, body) ʰb̲ox 0
  tiers ← tiered r̲eplicate₁ (x, y, body + (rough − body) ÷ 2.0, 0.72 × wide, 0.72 × deep, rough − body) ʰb̲ox 0
  bodies c̲at₁ tiers c̲at₁ spired r̲eplicate₁ (x, y, rough × 1.14, 0.34 × wide, 0.34 × deep, rough × 0.28) ʰb̲ox 0
}
Used in: ʰb̲uilt

On the towers

ˡr̲oofs : Any a => (Float, Int) -> a -> (Float, Float)

function · line 117

(lots, seed) nc:r_oofs 0: what stands on the roofs, as two tables of boxes: a machine on every roof and an aerial on some; and a beacon on every aerial and every spire

ˡr̲oofs ← { (t, seed) z →
  x ← 1 s̲elect₂ t
  y ← 2 s̲elect₂ t
  rough ← 3 s̲elect₂ t
  wide ← 4 s̲elect₂ t
  deep ← 5 s̲elect₂ t
  spired ← 8 s̲elect₂ t
  units ← (x + 0.2 × wide, y − 0.15 × deep, rough + 0.8, ʰf̲ill (lots, 3.2), ʰf̲ill (lots, 2.2), ʰf̲ill (lots, 1.6)) ʰb̲ox 0
  aerial ← (1.0 − spired) × f̲loat 1 × ((id, 7, seed) ˡr̲and 0) > 0.6
  mast ← 8.0 + 12.0 × (id, 8, seed) ˡr̲and 0
  masts ← (aerial > 0.5) r̲eplicate₁ (x − 0.2 × wide, y + 0.2 × deep, rough + mast ÷ 2.0, ʰf̲ill (lots, 0.25), ʰf̲ill (lots, 0.25), mast) ʰb̲ox 0
  tip ← rough + (mast × aerial) + (rough × 0.28) × spired
  lit ← (aerial + spired) > 0.5
  beacons ← lit r̲eplicate₁ (x − (0.2 × wide) × aerial, y + (0.2 × deep) × aerial, tip + 0.3, ʰf̲ill (lots, 0.7), ʰf̲ill (lots, 0.7), ʰf̲ill (lots, 0.7)) ʰb̲ox 0
  (units c̲at₁ masts, beacons)
}
Used in: ʰb̲uilt

ˡb̲ands : Any a => (Float, Int, Int) -> a -> Float

function · line 137

(lots, seed, k) nc:b_ands 0: the neon bands of color k (0 to 2): round the foot of the towers by the avenue, and under the tier of the tall ones

ˡb̲ands ← { (t, seed, k) z →
  x ← 1 s̲elect₂ t
  y ← 2 s̲elect₂ t
  wide ← 4 s̲elect₂ t
  deep ← 5 s̲elect₂ t
  body ← 10 s̲elect₂ t
  foot ← (x, y, ʰf̲ill (lots, 5.0), wide + 0.4, deep + 0.4, ʰf̲ill (lots, 0.3)) ʰb̲ox 0
  ledge ← (x, y, body + 0.15, wide + 0.3, deep + 0.3, ʰf̲ill (lots, 0.3)) ʰb̲ox 0
  low ← (col < 2) ∧ k = f̲loor 3.0 × (id, 9, seed) ˡr̲and 0
  up ← ((7 s̲elect₂ t) > 0.5) ∧ (col < 3) ∧ k = f̲loor 3.0 × (id, 10, seed) ˡr̲and 0
  (low r̲eplicate₁ foot) c̲at₁ up r̲eplicate₁ ledge
}
Used in: ʰb̲uilt

ratio : Float

value (private) · line 152
ratio ← 0.0 0.0 0.0 0.0 1.0 0.625 0.5625 0.5625 0.5625 0.5625 0.5625
Used in: ˡs̲creens

ˡs̲creens : Any a => (Float, Int, Int) -> a -> Float

function · line 158

(lots, seed, k) nc:s_creens 0: the screens of kind k on the walls facing the avenue, on most of the first towers: 0 bars, 1 rings, 2 rain, 3 tiles (pictures worked out from the time, any shape); 4 and 5 slide shows, 6 to 10 videos, each the shape of its pictures

ˡs̲creens ← { (t, seed, k) z →
  x ← 1 s̲elect₂ t
  y ← 2 s̲elect₂ t
  wide ← 4 s̲elect₂ t
  body ← 10 s̲elect₂ t
  shown ← (col = 0) ∧ (((id, 11, seed) ˡr̲and 0) > 0.25) ∧ k = f̲loor 11.0 × (id, 20, seed) ˡr̲and 0
  sw ← 5.0 + 7.0 × (id, 12, seed) ˡr̲and 0
  r ← (k + 1) s̲elect ratio
  sh ← ((5.0 + 11.0 × (id, 13, seed) ˡr̲and 0) × f̲loat 1 × r = 0.0) + sw × r
  sz ← 8.0 + ((body − 16.0) m̲in 34.0) × (id, 14, seed) ˡr̲and 0
  shown r̲eplicate₁ (x − side × 0.3 + wide ÷ 2.0, y, sz + sh ÷ 2.0, ʰf̲ill (lots, 0.4), sw, sh) ʰb̲ox 0
}
Used in: ʰb̲uilt

The street

blocks : Int

value (private) · line 174
blocks ← (cols × rows) d̲iv 2
Used in: bid, bside, bcol, brow, slabs

bid : Int

value (private) · line 175
bid ← (r̲ange blocks) − 1
Used in: bside, bcol, brow

bside : Float

value (private) · line 176
bside ← (f̲loat 2 × bid d̲iv blocks d̲iv 2) − 1.0
Used in: bx

bcol : Int

value (private) · line 177
bcol ← (bid m̲od blocks d̲iv 2) d̲iv rows d̲iv 2
Used in: bx

brow : Int

value (private) · line 178
brow ← (bid m̲od blocks d̲iv 2) m̲od rows d̲iv 2
Used in: by

bx : Float

value (private) · line 179
bx ← bside × 28.0 + 46.0 × f̲loat bcol
Used in: slabs

by : Float

value (private) · line 180
by ← -225.0 + 50.0 × f̲loat brow
Used in: slabs

slabs : Float

value (private) · line 181
slabs ← (bx, by, ʰf̲ill (blocks, 0.15), ʰf̲ill (blocks, 37.0), ʰf̲ill (blocks, 41.0), ʰf̲ill (blocks, 0.3)) ʰb̲ox 0
Used in: ʰb̲uilt

dashes : Int

value (private) · line 184
dashes ← 62
Used in: dy, paint

dy : Float

value (private) · line 185
dy ← -244.0 + 8.0 × f̲loat (r̲ange dashes) − 1
Used in: paint

paint : Float

value (private) · line 186
paint ← (ʰf̲ill (dashes, 0.0), dy, ʰf̲ill (dashes, 0.012), ʰf̲ill (dashes, 0.18), ʰf̲ill (dashes, 3.0), ʰf̲ill (dashes, 0.02)) ʰb̲ox 0
Used in: ʰb̲uilt

posts : Int

value (private) · line 189
posts ← 32
Used in: pside, py, stems, arms, bulbs, glows

pside : Float

value (private) · line 190
pside ← (f̲loat 2 × ((r̲ange posts) − 1) m̲od 2) − 1.0
Used in: stems, arms, bulbs, glows

py : Float

value (private) · line 191
py ← -232.0 + 30.0 × f̲loat ((r̲ange posts) − 1) d̲iv 2
Used in: stems, arms, bulbs, glows

stems : Float

value (private) · line 192
stems ← (pside × 9.7, py, ʰf̲ill (posts, 3.6), ʰf̲ill (posts, 0.18), ʰf̲ill (posts, 0.18), ʰf̲ill (posts, 7.2)) ʰb̲ox 0
Used in: ʰb̲uilt

arms : Float

value (private) · line 193
arms ← (pside × 8.9, py, ʰf̲ill (posts, 7.2), ʰf̲ill (posts, 1.8), ʰf̲ill (posts, 0.2), ʰf̲ill (posts, 0.14)) ʰb̲ox 0
Used in: ʰb̲uilt

bulbs : Float

value (private) · line 194
bulbs ← (pside × 8.4, py, ʰf̲ill (posts, 7.1), ʰf̲ill (posts, 0.9), ʰf̲ill (posts, 0.22), ʰf̲ill (posts, 0.06)) ʰb̲ox 0
Used in: ʰb̲uilt

glows : Float

value (private) · line 195
glows ← (8, (pside × 8.4) c̲at py c̲at (ʰf̲ill (posts, 6.8)) c̲at (ʰf̲ill (posts, 255)) c̲at (ʰf̲ill (posts, 190)) c̲at (ʰf̲ill (posts, 120)) c̲at (ʰf̲ill (posts, 450)) c̲at ʰf̲ill (posts, 0.15)) ʰc̲ols 0
Used in: ʰb̲uilt

spans : Float

value (private) · line 199
spans ← 2 7 r̲eshape 0.0 -28.0 15.5 27.0 5.0 3.4 0.0  0.0 97.0 19.0 27.0 5.0 3.4 0.0
Used in: ʰb̲uilt

strips : Float

value (private) · line 200
strips ← 2 7 r̲eshape 0.0 -28.0 13.7 24.0 0.3 0.12 0.0  0.0 97.0 17.2 24.0 0.3 0.12 0.0
Used in: ʰb̲uilt

pylons : Float

value (private) · line 201
pylons ← 2 7 r̲eshape -31.0 252.0 36.0 6.0 6.0 72.0 0.0  31.0 252.0 36.0 6.0 6.0 72.0 0.0
Used in: ʰb̲uilt

great : Float

value (private) · line 202
great ← 1 7 r̲eshape 0.0 251.0 44.0 56.0 0.5 31.5 0.0
Used in: ʰb̲uilt

vents : Int

value (private) · line 205
vents ← 7
Used in: vy, vx, plumes

vy : Float

value (private) · line 206
vy ← -210.0 + 68.0 × f̲loat (r̲ange vents) − 1
Used in: plumes

vx : Float

value (private) · line 207
vx ← 7.2 × (f̲loat 2 × ((r̲ange vents) − 1) m̲od 2) − 1.0
Used in: plumes

plumes : Float

value (private) · line 208
plumes ← (6, vx c̲at vy c̲at (ʰf̲ill (vents, 5.5)) c̲at (ʰf̲ill (vents, 5.0)) c̲at (ʰf̲ill (vents, 5.0)) c̲at ʰf̲ill (vents, 11.0)) ʰc̲ols 0
Used in: ˡc̲ity

Traffic

cars : Int

value (private) · line 214
cars ← 32
Used in: cid, ˡc̲ars

cid : Int

value (private) · line 215
cid ← (r̲ange cars) − 1
Used in: lane, ˡc̲ars

lane : Int

value (private) · line 216
lane ← cid m̲od 4
Used in: north, cx

north : Float

value (private) · line 217
north ← (f̲loat 2 × lane d̲iv 2) − 1.0
Used in: cx, ˡc̲ars

cx : Float

value (private) · line 218
cx ← north × 2.6 + 3.6 × f̲loat lane m̲od 2
Used in: ˡc̲ars

ˡc̲ars : Int -> Float

function · line 225

nc:c_ars seed: the cars on the avenue, a row each: from x y z to x y z in the film (what cy:f_leet takes)

      "nc:" u̲se< "NeonCity"
      s̲hape ⁿᶜc̲ars 7
32 6
ˡc̲ars ← { seed →
  y ← north × -250.0 + (64.0 × f̲loat cid d̲iv 4) + 30.0 × (cid, 21, seed) ˡr̲and 0
  run ← north × ˡseconds × 9.0 + 9.0 × (cid, 22, seed) ˡr̲and 0
  (6, cx c̲at y c̲at (ʰf̲ill (cars, 0.0)) c̲at cx c̲at (y + run) c̲at ʰf̲ill (cars, 0.0)) ʰc̲ols 0
}
Used in: ʰt̲raffic

fliers : Int

value (private) · line 233
fliers ← 27
Used in: fid

fid : Int

value (private) · line 234
fid ← (r̲ange fliers) − 1
Used in: street, ˡf̲liers

street : Int

value (private) · line 235
street ← fid m̲od 9
Used in: east, fy, ˡf̲liers

east : Float

value (private) · line 236
east ← (f̲loat 2 × street m̲od 2) − 1.0
Used in: ˡf̲liers

fy : Float

value (private) · line 237
fy ← -200.0 + 50.0 × f̲loat street
Used in: ˡf̲liers

high2 : Int

value (private) · line 238
high2 ← 10
Used in: hid

hid : Int

value (private) · line 239
hid ← (r̲ange high2) − 1
Used in: hn, hz, ˡf̲liers

hn : Float

value (private) · line 240
hn ← (f̲loat 2 × hid m̲od 2) − 1.0
Used in: ˡf̲liers

hz : Float

value (private) · line 241
hz ← 62.0 + 9.0 × f̲loat hid m̲od 2
Used in: ˡf̲liers

ˡf̲liers : Int -> Float

function · line 248

nc:f_liers seed: the fliers, rows as nc:c_ars: along the cross streets, then over the avenue

      "nc:" u̲se< "NeonCity"
      s̲hape ⁿᶜf̲liers 7
37 6
ˡf̲liers ← { seed →
  fz ← 26.0 + (11.0 × f̲loat street m̲od 3) + 4.0 × (fid, 23, seed) ˡr̲and 0
  x ← east × -330.0 + (150.0 × f̲loat fid d̲iv 9) + 60.0 × (fid, 24, seed) ˡr̲and 0
  run ← east × ˡseconds × 22.0 + 16.0 × (fid, 25, seed) ˡr̲and 0
  y ← hn × -300.0 + (110.0 × f̲loat hid d̲iv 2) + 40.0 × (hid, 26, seed) ˡr̲and 0
  across ← (6, x c̲at fy c̲at fz c̲at (x + run) c̲at fy c̲at fz) ʰc̲ols 0
  across c̲at₁ (6, (hn × 5.5) c̲at y c̲at hz c̲at (hn × 5.5) c̲at (y + hn × ˡseconds × 30.0) c̲at hz) ʰc̲ols 0
}
Used in: ʰt̲raffic

The camera

ˡtimes : Float

value · line 264

nc:times: the times of the flight (cy:f_ly), with nc:eyes and nc:aims: from over the skyline at the south end, down between the towers, under the first bridge to the height of a car's roof, along the puddles, and up a little to the great screen at the north end

ˡtimes ← 0.0 3.0 6.0 9.0 12.0 15.0
Used in: ˡc̲ity

ˡeyes : Float

value · line 266

nc:eyes: where the camera is at each of nc:times (6 by 3)

ˡeyes ← 6 3 r̲eshape 0.0 -330.0 150.0  0.0 -255.0 78.0  -2.0 -170.0 26.0  1.6 -80.0 5.0  -1.2 20.0 2.3  0.0 120.0 5.5
Used in: ˡc̲ity

ˡaims : Float

value · line 268

nc:aims: what it looks at then (6 by 3)

ˡaims ← 6 3 r̲eshape 0.0 -150.0 40.0  0.0 -90.0 26.0  0.0 -40.0 10.0  0.0 30.0 5.0  0.0 130.0 8.0  0.0 250.0 34.0
Used in: ˡc̲ity

The scene

ʰs̲kins : Char -> Char

function (private) · line 273
ʰs̲kins ← { where →
  ⍝ the pictures: two slide shows, five videos, and the great screen's
  (((("skin 0", 60 62 70, 255 220 170, 180 230 255, 1.6 3.2, 0.3, 2.5) ᶜʸf̲acade 0) c̲at (("skin 1", 80 60 60, 255 120 180, 255 230 160, 2.4 3.0, 0.2, 2.5) ᶜʸf̲acade 0)) c̲at
    ((("skin 2", 40 50 60, 120 255 230, 200 160 255, 1.2 3.6, 0.4, 2.0) ᶜʸf̲acade 0)) c̲at
    ((("street", 62 62 65, 0.45, 5.0, 0.25) ᶜʸw̲et 0) c̲at (("walk", 70 70 74, 0.55, 0.0) ᶜʸs̲urface 0)) c̲at
    ((("dark", 46 46 50, 0.45, 0.7) ᶜʸs̲urface 0) c̲at (("paint", 200 200 190, 0.6, 0.0) ᶜʸs̲urface 0) c̲at (("shell", 30 34 44, 0.25, 0.9) ᶜʸs̲urface 0)) c̲at
    ((("neon 0", 255 13 102, 8.0) ᶜʸn̲eon 0) c̲at (("neon 1", 13 204 255, 8.0) ᶜʸn̲eon 0) c̲at (("neon 2", 255 128 13, 8.0) ᶜʸn̲eon 0)) c̲at
    ((("warm", 255 190 120, 20.0) ᶜʸn̲eon 0) c̲at (("head", 255 245 220, 40.0) ᶜʸn̲eon 0) c̲at (("tail", 255 5 5, 40.0) ᶜʸn̲eon 0) c̲at (("beacon", 255 20 10, 30.0) ᶜʸn̲eon 0)) c̲at
    ((("screen 0", "bars", 255 26 128, 26 230 255, 0.5, 5.0) ᶜʸs̲creen 0) c̲at (("screen 1", "rings", 255 153 26, 77 26 255, 0.4, 5.0) ᶜʸs̲creen 0)) c̲at
    ((("screen 2", "rain", 26 255 102, 204 255 230, 0.6, 6.0) ᶜʸs̲creen 0) c̲at (("screen 3", "tiles", 255 26 51, 26 102 255, 2.0, 5.0) ᶜʸs̲creen 0)) c̲at
    ((ᶜʸm̲edia where) c̲at (("screen 4", "art", 16, 4.0, 1.6) ᶜʸs̲lides 0) c̲at (("screen 5", "xetal", 12, 4.0, 1.6) ᶜʸs̲lides 0)) c̲at
    ((("screen 6", "voxels.webm", 1.6) ᶜʸr̲eel 0) c̲at (("screen 7", "rubik.webm", 1.6) ᶜʸr̲eel 0) c̲at (("screen 8", "life.webm", 1.6) ᶜʸr̲eel 0)) c̲at
    ((("screen 9", "stone.webm", 1.6) ᶜʸr̲eel 0) c̲at (("screen 10", "cosy.webm", 1.6) ᶜʸr̲eel 0)) c̲at
    (("great", "matmul.webm", 1.8) ᶜʸr̲eel 0))
}
Used in: ˡc̲ity

ʰb̲uilt : Int -> Char

function (private) · line 290
ʰb̲uilt ← { seed →
  lt ← ˡl̲ots seed
  (units, beacons) ← (lt, seed) ˡr̲oofs 0
  (((("ground", 1 7 r̲eshape 0.0 0.0 -0.5 1400.0 1400.0 1.0 0.0, "street") ᶜʸb̲oxes 0) c̲at (("walks", slabs, "walk") ᶜʸb̲oxes 0) c̲at (("dashes", paint, "paint") ᶜʸb̲oxes 0)) c̲at
    ((("towers 0", (lt, 0) ˡt̲owers 0, "skin 0") ᶜʸb̲oxes 0) c̲at (("towers 1", (lt, 1) ˡt̲owers 0, "skin 1") ᶜʸb̲oxes 0) c̲at (("towers 2", (lt, 2) ˡt̲owers 0, "skin 2") ᶜʸb̲oxes 0)) c̲at
    ((("units", units, "dark") ᶜʸb̲oxes 0) c̲at (("beacons", beacons, "beacon") ᶜʸb̲oxes 0)) c̲at
    ((("bands 0", (lt, seed, 0) ˡb̲ands 0, "neon 0") ᶜʸb̲oxes 0) c̲at (("bands 1", (lt, seed, 1) ˡb̲ands 0, "neon 1") ᶜʸb̲oxes 0) c̲at (("bands 2", (lt, seed, 2) ˡb̲ands 0, "neon 2") ᶜʸb̲oxes 0)) c̲at
    ((("screens 0", (lt, seed, 0) ˡs̲creens 0, "screen 0") ᶜʸb̲oxes 0) c̲at (("screens 1", (lt, seed, 1) ˡs̲creens 0, "screen 1") ᶜʸb̲oxes 0)) c̲at
    ((("screens 2", (lt, seed, 2) ˡs̲creens 0, "screen 2") ᶜʸb̲oxes 0) c̲at (("screens 3", (lt, seed, 3) ˡs̲creens 0, "screen 3") ᶜʸb̲oxes 0)) c̲at
    ((("screens 4", (lt, seed, 4) ˡs̲creens 0, "screen 4") ᶜʸb̲oxes 0) c̲at (("screens 5", (lt, seed, 5) ˡs̲creens 0, "screen 5") ᶜʸb̲oxes 0)) c̲at
    ((("screens 6", (lt, seed, 6) ˡs̲creens 0, "screen 6") ᶜʸb̲oxes 0) c̲at (("screens 7", (lt, seed, 7) ˡs̲creens 0, "screen 7") ᶜʸb̲oxes 0)) c̲at
    ((("screens 8", (lt, seed, 8) ˡs̲creens 0, "screen 8") ᶜʸb̲oxes 0) c̲at (("screens 9", (lt, seed, 9) ˡs̲creens 0, "screen 9") ᶜʸb̲oxes 0)) c̲at
    ((("screens 10", (lt, seed, 10) ˡs̲creens 0, "screen 10") ᶜʸb̲oxes 0)) c̲at
    ((("posts", stems c̲at₁ arms, "dark") ᶜʸb̲oxes 0) c̲at (("bulbs", bulbs, "warm") ᶜʸb̲oxes 0) c̲at (("lamps", glows) ᶜʸl̲amps 0)) c̲at
    ((("spans", spans, "skin 0") ᶜʸb̲oxes 0) c̲at (("strips", strips, "neon 1") ᶜʸb̲oxes 0)) c̲at
    (("pylons", pylons, "dark") ᶜʸb̲oxes 0) c̲at (("great", great, "great") ᶜʸb̲oxes 0))
}
Used in: ˡc̲ity

ʰs̲igns : Any a => a -> Char

function (private) · line 309
ʰs̲igns ← { z →
  (((("sign 1", "X_eTaL", -10.4 -150.0 34.0, 2.6, 0, 1, "neon 0") ᶜʸs̲ign 0) c̲at (("sign 2", "ARRAYS", 10.4 -95.0 30.0, 2.4, 0, 1, "neon 1") ᶜʸs̲ign 0)) c̲at
    ((("sign 3", "RHO", -10.4 -52.0 20.0, 2.2, 0, 1, "neon 2") ᶜʸs̲ign 0) c̲at (("sign 4", "OPEN 24H", 0.0 -30.8 15.5, 1.6, 0, 0, "neon 0") ᶜʸs̲ign 0)) c̲at
    ((("sign 5", "IOTA", 10.4 14.0 22.0, 2.2, 0, 1, "neon 0") ᶜʸs̲ign 0) c̲at (("sign 6", "NOODLES", -10.4 52.0 24.0, 2.0, 0, 1, "neon 1") ᶜʸs̲ign 0)) c̲at
    (("sign 7", "KERNEL", 0.0 94.2 19.0, 1.6, 0, 0, "neon 2") ᶜʸs̲ign 0) c̲at (("sign 8", "HOTEL", 10.4 150.0 30.0, 2.6, 0, 1, "neon 2") ᶜʸs̲ign 0))
}
Used in: ˡc̲ity

ʰt̲raffic : Int -> Char

function (private) · line 317
ʰt̲raffic ← { seed →
  (((ᶜʸm̲odel "car") c̲at (("car body", 2 7 r̲eshape 0.0 0.0 0.55 4.4 1.9 0.6 0.0  -0.3 0.0 1.1 2.4 1.7 0.55 0.0, "shell", "car") ᶜʸp̲arts 0)) c̲at
    ((("car head", 2 7 r̲eshape 2.2 0.6 0.6 0.06 0.35 0.15 0.0  2.2 -0.6 0.6 0.06 0.35 0.15 0.0, "head", "car") ᶜʸp̲arts 0)) c̲at
    ((("car tail", 1 7 r̲eshape -2.2 0.0 0.72 0.06 1.6 0.1 0.0, "tail", "car") ᶜʸp̲arts 0)) c̲at
    ((ᶜʸm̲odel "flier") c̲at (("flier body", 3 7 r̲eshape 0.0 0.0 0.0 5.2 2.2 0.7 0.0  -0.4 0.0 0.55 2.6 1.9 0.5 0.0  -2.3 0.0 0.7 0.9 2.8 0.08 0.0, "shell", "flier") ᶜʸp̲arts 0)) c̲at
    ((("flier head", 1 7 r̲eshape 2.6 0.0 0.0 0.06 1.5 0.12 0.0, "head", "flier") ᶜʸp̲arts 0) c̲at (("flier tail", 1 7 r̲eshape -2.6 0.0 0.1 0.06 1.9 0.12 0.0, "tail", "flier") ᶜʸp̲arts 0)) c̲at
    ((("flier under", 1 7 r̲eshape 0.0 0.0 -0.4 4.0 1.6 0.05 0.0, "neon 1", "flier") ᶜʸp̲arts 0)) c̲at
    (("cars", "car", ˡc̲ars seed) ᶜʸf̲leet 0) c̲at (("fliers", "flier", ˡf̲liers seed) ᶜʸf̲leet 0))
}
Used in: ˡc̲ity

ˡc̲ity : Any e => (Int, Char, a, b, c, d, Char) -> e -> Char

function · line 337

(seed, media, width, height, fps, samples, device) nc:c_ity 0: the city of that seed as the calls of a player, without the player; media is the folder of the screens' pictures (slides and videos: the three extension's web/static/media), from where the player runs. The picture (cy:s_tage) for nc:seconds, the sky, the materials, the city, its signs and traffic, haze over it all, steam, the camera's flight and the report. Blender's player is cy:head (nc:s_cene); a player in another renderer that defines the same functions draws the same city from the same text (Three.xtl's, in a browser).

ˡc̲ity ← { (seed, where, w, h, fps, samples, device) z →
  ((((w, h, fps, ˡseconds, samples, device) ᶜʸs̲tage 0) c̲at (("AgX - Punchy", 0.0, 0.5) ᶜʸl̲ook 0) c̲at ((30 14 40, 2 3 8, 1.0) ᶜʸs̲ky 0)) c̲at
    ((ʰs̲kins where) c̲at (ʰb̲uilt seed) c̲at (ʰs̲igns 0) c̲at ʰt̲raffic seed) c̲at
    ((("haze", 1 6 r̲eshape 0.0 0.0 110.0 1300.0 1300.0 220.0, 150 165 255, 0.0012, 0.5) ᶜʸf̲og 0) c̲at (("vent", plumes, 255 255 255, 1.2, 1.5) ᶜʸs̲team 0)) c̲at
    ((ˡtimes, ˡeyes, ˡaims, 24, 2.0) ᶜʸf̲ly 0) c̲at ((1.0, 0.6, 0.6) ᶜʸb̲loom 0) c̲at ᶜʸreport)
}
Used in: ˡs̲cene, scene

ˡs̲cene : Any e => (a, b, c, d, Char) -> e -> Char

function · line 348

(width, height, fps, samples, device) nc:s_cene 0: the whole script Blender runs but its rendering, for the film's city (nc:seed): cy:head, then nc:c_ity. What to render is the caller's, added after: cy:s_till, or cy:f_rames and cy:e_ncode.

ˡs̲cene ← { (w, h, fps, samples, device) z → ᶜʸhead c̲at (ˡseed, ˡmedia, w, h, fps, samples, device) ˡc̲ity 0 }
Used in: script, script